读取TXT并保存到数据库代码,ASP代码库,德仔网

代码语言
代码分类
【ASP】读取TXT并保存到数据库
作者:Dezai.CN / 发布于2013/7/16/ 1602

	<!--#include file="../include/db_conn.asp"-->
	<!--#include file="../include/CheckLogin.asp"-->
	<!--#include file="../include/WhbUpload.ini"-->
	<!--#include file="../include/WhbArray.ini"-->
	<html>
	<head>
	<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
	<link href="admin.css" rel="stylesheet" type="text/css"/>
	<script language="javascript">
	function wordmessage(){
	if(document.form1.content.value.length><%=sys_textareamax%>) {
	 alert('短信内容限定为70个字符，您已经达到字数上限！');
	 document.form1.content.value=(document.form1.content.value).substr(0,<%=sys_textareamax%>)
	}else
	{
	 var leftnum=<%=sys_textareamax%>-document.form1.content.value.length;
	 inforid.innerHTML="剩余短信字数：<font class=redstyle>"+leftnum+" </font>字." ;
	}
	}

	function CheckForm()
	{
	if(document.form1.mobile.value=="" && document.form1.myfile.value=="")
	{
	 alert("手机号码和上传文件不能同时为空，请认真操作！");
	 return false;
	}
	if(document.form1.mobile.value!="" && document.form1.mobile.value.length!=11)
	{
	 alert("手机号码填写不正确，请认真填写！");
	 return false;
	}
	if(document.form1.content.value.length==0)
	{
	 alert("短信内容不能为空,请认真填写！");
	 return false;
	}
	if (confirm("请再次确认短信内容，一旦发送将无法修改！")==true)
	{
	 document.form1.add.disabled=true;
	 document.form1.add.value="短信正在提交，请稍候...";
	 return true;
	}
	return false;
	}


	</script>
	</head>
	<body>
	<form name="form1" method="post" action="?act=send" enctype="multipart/form-data" onSubmit="return CheckForm(this);">
	 请输入短信内容(限<%=sys_textareamax%>字)：
	 
	 <label>
	 <textarea name="content" cols="45" rows="8" id="content" onblur="javascript:wordmessage();" onKeyUp="javascript:wordmessage();" onMouseUp="javascript:wordmessage();" ></textarea>
	 </label>
	 
	 <span id="inforid"></span>
	 请输入对方手机号码：
	 <input name="mobile" type="text" id="mobile" size="28" maxlength="11" onkeyup="this.value=this.value.replace(/\D/g,'')" onafterpaste="this.value=this.value.replace(/\D/g,'')">
	
	 TXT文本批量上传：
	 <label>
	 <input type="File" name="myfile" id="myfile">
	 </label>
	 
	 
	 <label>
	 <input type="submit" name="add" id="add" value="发送短信" class="btn">
	 </label>
	 <label>
	 <input type="submit" name="cancel" id="cancel" value="重新填写" class="btn">
	 </label>
	 
	</form>
	<%
	if request("act")="send" then
	set upload=new WhbUpload '建立上传对象
	set file=upload.file("myfile")'file1对应前台表单中的type=file,name=myfile

	mobile=upload.Form("mobile")
	content=upload.Form("content")

	'发送记述
	mycount=0

	if mobile<>"" then'如果有单个
	sqlstr="insert into Sys_sms(recv_mobile,sms_content,user_id,sms_status,regtime)values('"&mobile&"','"&content&"',"&session("user_id")&",1,getdate())"
	conn.execute sqlstr
	mycount=1
	end if

	'如果用户上传了文件
	if file.FileSize>0 then
	'首先保存
	filepath=Server.mappath("./uploadfile/"&file.FileName)
	file.saveAs filepath

	'读TXT文件
	 Set fso = Server.CreateObject("Scripting.FileSystemObject")
	 '如果文件存在
	 IF (fso.FileExists(filepath)) Then
	 Set fout = fso.OpenTextFile(filepath,1,false)
	
	 dim arrindex,myarray
	 arrindex=0
	 myarray=array()
	 '按行读取并保存到数组
	 while not fout.AtEndOfStream
	 redim Preserve myarray(arrindex)'此步骤不可省略
	 myarray(arrindex)=trim(fout.readline)
	 arrindex=arrindex+1
	 wend
	 fout.close
	 set fout=nothing
	
	
	 '数据库事务处理
	 conn.BeginTrans '事务开始

	 On Error Resume Next
	 for each element in myarray'此处必须用EACH
	 sqlstr="insert into Sys_sms(recv_mobile,sms_content,user_id,sms_status,regtime)values('"&element&"','"&content&"',"&session("user_id")&",1,getdate())"
	 'response.Write sqlstr
	 'response.End()
	 conn.execute sqlstr
	 next
	
	 if err.number =0 then
	 conn.CommitTrans '如果没有conn错误，则执行事务提交
	 mycount=mycount+ubound(myarray)+1
	 else
	 conn.RollbackTrans '否则回滚
	 '回滚后的其他操作
	 strerr=err.Description
	 Response.Write "数据库错误！错误日志：<font class=redstyle>"&strerr &"</font>"
	 Response.End
	 end if
	
	 else
	 Response.Write "TXT文件在保存过程中出现错误，无法正常读取。"
	 Response.End
	 End If
	 Set fso=nothing
	end if

	set file=nothing

	response.Write "恭喜，短信发送成功！累计发送条数：<font class=redstyle>"&mycount&"</font>条。"
	end if
	%>
	</body>
	</html>
试试其它关键字
　读取TXT　
同语言下
可能有用的
Dezai.CN贡献的其它代码(4037)